/* =====================================================================
   CAJA EL OLIVO (78080895) - CONSOLIDADO - 08-10-2026
   Correr en SSMS, instancia LOCAL de la caja (SERVIDOR\SQLEXPRESS),
   base PRIXUS_78080895. No hay que reiniciar el servicio PrixusSyncAgent.
   Se puede correr mas de una vez.
   1) Procedimientos de aplicacion vigentes (eliminar articulo en el
      central lo borra en la caja).
   2) Limpieza de los articulos ya eliminados en el central.
   3) Verificacion: la ultima consulta debe devolver 0 filas.
   ===================================================================== */
USE PRIXUS_78080895;
GO

-- =============================================================================
-- Ticket #5202 (Prixus Sync, [DESKTOP]) - SPs de aplicación de eventos
-- Se crean en la BD LOCAL de la caja. El agente los invoca dentro de UNA
-- transacción junto con el registro en PriSyncEventosAplicados/PriSyncEstado.
-- Reglas: upsert por clave natural. delete: el artículo se borra igual que
-- en el central (con respaldo de desactivación si la base no deja borrar);
-- familia, subfamilia y promoción se desactivan. Campos según Anexo A del
-- requerimiento #5199.
-- Pendiente Fase 0: cierre campo a campo definitivo con equipos desktop y
-- BD (precio y promoción se agregan cuando ese mapeo esté firmado).
-- =============================================================================

-- invArticulos tiene un índice sobre codbus (columna calculada): cualquier
-- INSERT/UPDATE/DELETE exige QUOTED_IDENTIFIER ON, y el procedimiento guarda
-- la opción con la que fue creado. Se fija acá para que dé lo mismo si el
-- script se corre desde SSMS, sqlcmd o un runner.
SET QUOTED_IDENTIFIER ON;
SET ANSI_NULLS ON;
GO

-- ------------------------------- FAMILIA ------------------------------------
IF OBJECT_ID(N'dbo.sp_ApiPos_Familia_Apply', N'P') IS NOT NULL DROP PROCEDURE dbo.sp_ApiPos_Familia_Apply;
GO
CREATE PROCEDURE dbo.sp_ApiPos_Familia_Apply
    @codfam       VARCHAR(50),
    @nomfam       VARCHAR(100),
    -- Opcionales: llegan NULL cuando el modulo que publica no los envia.
    -- NULL = "no me lo mandaron": en un alta toma el default, en una
    -- modificacion la columna se deja como estaba.
    @coment       VARCHAR(200)  = NULL,
    @facturable   INT           = NULL,
    @controlstock INT           = NULL,
    @exento       INT           = NULL,
    @servicio     INT           = NULL,
    @operation    VARCHAR(10)   = 'upsert'
AS
BEGIN
    SET NOCOUNT ON;

    IF @operation = 'delete'
    BEGIN
        -- Desactivación lógica: la familia deja de ofrecerse pero las
        -- referencias históricas quedan intactas.
        UPDATE dbo.invFamilia SET facturable = 0 WHERE codfam = @codfam;
        RETURN;
    END

    IF EXISTS (SELECT 1 FROM dbo.invFamilia WHERE codfam = @codfam)
        -- Modificacion: cada columna conserva su valor si el campo no vino.
        UPDATE dbo.invFamilia
           SET nomfam       = @nomfam,
               coment       = ISNULL(@coment,       coment),
               facturable   = ISNULL(@facturable,   facturable),
               controlstock = ISNULL(@controlstock, controlstock),
               exento       = ISNULL(@exento,       exento),
               servicio     = ISNULL(@servicio,     servicio),
               logmod       = 'SYNC',
               fecmod       = GETDATE()
         WHERE codfam = @codfam;
    ELSE
        INSERT INTO dbo.invFamilia (codfam, nomfam, coment, facturable, controlstock, exento, servicio,
                loging, fecing, logmod, fecmod)
        VALUES (@codfam, @nomfam, ISNULL(@coment, ''), ISNULL(@facturable, 1),
                ISNULL(@controlstock, 1), ISNULL(@exento, 0), ISNULL(@servicio, 0),
                'SYNC', GETDATE(), 'SYNC', GETDATE());
END
GO

-- ------------------------------ SUBFAMILIA ----------------------------------
IF OBJECT_ID(N'dbo.sp_ApiPos_SubFamilia_Apply', N'P') IS NOT NULL DROP PROCEDURE dbo.sp_ApiPos_SubFamilia_Apply;
GO
CREATE PROCEDURE dbo.sp_ApiPos_SubFamilia_Apply
    @codfam    VARCHAR(50),
    @codsub    VARCHAR(50),
    @nomsub    VARCHAR(100),
    -- Opcional: NULL significa "no me lo mandaron" y no pisa la columna.
    @coment    VARCHAR(200) = NULL,
    @operation VARCHAR(10)  = 'upsert'
AS
BEGIN
    SET NOCOUNT ON;

    IF @operation = 'delete'
        RETURN;  -- Sin flag de desactivación en invSubFamilia: el delete lógico
                 -- se resuelve desactivando los artículos; definir en Fase 0.

    IF EXISTS (SELECT 1 FROM dbo.invSubFamilia WHERE codfam = @codfam AND codsub = @codsub)
        -- Modificacion: coment conserva su valor si el campo no vino.
        UPDATE dbo.invSubFamilia
           SET nomsub = @nomsub,
               coment = ISNULL(@coment, coment),
               logmod = 'SYNC',
               fecmod = GETDATE()
         WHERE codfam = @codfam AND codsub = @codsub;
    ELSE
        INSERT INTO dbo.invSubFamilia (codfam, codsub, nomsub, coment, loging, fecing, logmod, fecmod)
        VALUES (@codfam, @codsub, @nomsub, ISNULL(@coment, ''), 'SYNC', GETDATE(), 'SYNC', GETDATE());
END
GO

-- ------------------------------- ARTÍCULO -----------------------------------
-- Solo campos de definición (Anexo A). Los de stock/costos/saldos NO viajan
-- y este SP jamás los toca.
IF OBJECT_ID(N'dbo.sp_ApiPos_Articulo_Apply', N'P') IS NOT NULL DROP PROCEDURE dbo.sp_ApiPos_Articulo_Apply;
GO
CREATE PROCEDURE dbo.sp_ApiPos_Articulo_Apply
    @codfam      VARCHAR(50),
    @codsub      VARCHAR(50),
    @codart      VARCHAR(50),
    @nomart      VARCHAR(500),
    -- Los opcionales llegan NULL cuando el modulo que publica no los envio.
    -- NULL significa "no me lo mandaron": en un alta toma el valor por
    -- defecto y en una modificacion la columna se deja como estaba.
    @nomart2     VARCHAR(500)  = NULL,
    @codbar      VARCHAR(50)   = NULL,
    @codalt      VARCHAR(255)  = NULL,
    @coduni      INT           = NULL,
    @medalt      INT           = NULL,
    @activo      INT           = NULL,
    @exentoArt   INT           = NULL,
    @imp_adi     INT           = NULL,
    @impbase     DECIMAL(18,4) = NULL,
    @impvariable DECIMAL(18,4) = NULL,
    @preciovar   INT           = NULL,
    @balanza     INT           = NULL,
    @coment      VARCHAR(MAX)  = NULL,
    @operation   VARCHAR(10)   = 'upsert'
AS
BEGIN
    SET NOCOUNT ON;

    -- Misma normalizacion del CRUD canonico del master: la caja debe
    -- terminar con exactamente la misma fila.
    SET @codfam  = UPPER(LTRIM(RTRIM(@codfam)));
    SET @codsub  = UPPER(LTRIM(RTRIM(@codsub)));
    SET @codart  = UPPER(LTRIM(RTRIM(@codart)));
    SET @nomart  = LTRIM(RTRIM(ISNULL(@nomart, '')));
    IF @nomart2 IS NOT NULL SET @nomart2 = LTRIM(RTRIM(@nomart2));

    -- codbus (codigo de busqueda que enlaza articulo, precios y promociones) es
    -- una columna calculada persistida = codfam+codsub+codart. No se escribe:
    -- SQL Server la deriva sola al insertar o actualizar la clave.

    IF @operation = 'delete'
    BEGIN
        -- Eliminación real, igual que en el central (el central ya validó que
        -- el artículo no tenga uso antes de borrarlo). Si esta base no deja
        -- borrar la fila, queda desactivada: así la cola de eventos no se frena.
        BEGIN TRY
            DELETE FROM dbo.invArticulos
             WHERE codfam = @codfam AND codsub = @codsub AND codart = @codart;
        END TRY
        BEGIN CATCH
            IF XACT_STATE() <> -1
                UPDATE dbo.invArticulos
                   SET activo = 0, logmod = 'SYNC', fecmod = GETDATE()
                 WHERE codfam = @codfam AND codsub = @codsub AND codart = @codart;
        END CATCH
        RETURN;
    END

    IF EXISTS (SELECT 1 FROM dbo.invArticulos
                WHERE codfam = @codfam AND codsub = @codsub AND codart = @codart)
        -- Modificacion: cada columna conserva su valor si el campo no vino.
        UPDATE dbo.invArticulos
           SET nomart      = @nomart,
               nomart2     = CASE WHEN @nomart2 IS NULL OR @nomart2 = '' THEN nomart2 ELSE @nomart2 END,
               codbar      = ISNULL(@codbar,      codbar),
               codalt      = ISNULL(@codalt,      codalt),
               coduni      = ISNULL(@coduni,      coduni),
               medalt      = ISNULL(@medalt,      medalt),
               activo      = ISNULL(@activo,      activo),
               exentoArt   = ISNULL(@exentoArt,   exentoArt),
               imp_adi     = ISNULL(@imp_adi,     imp_adi),
               impbase     = ISNULL(@impbase,     impbase),
               impvariable = ISNULL(@impvariable, impvariable),
               preciovar   = ISNULL(@preciovar,   preciovar),
               balanza     = ISNULL(@balanza,     balanza),
               coment      = ISNULL(@coment,      coment)
         WHERE codfam = @codfam AND codsub = @codsub AND codart = @codart;
    ELSE
        -- Alta: lo que no vino toma el valor por defecto de la columna.
        INSERT INTO dbo.invArticulos
            (codfam, codsub, codart, nomart, nomart2, codbar, codalt,
             coduni, medalt, activo, exentoArt, imp_adi, impbase, impvariable,
             preciovar, balanza, coment, comision, monori, proced,
             fechaing, loging, fecing, logmod, fecmod)
        VALUES
            (@codfam, @codsub, @codart, @nomart,
             CASE WHEN @nomart2 IS NULL OR @nomart2 = '' THEN @nomart ELSE @nomart2 END,
             ISNULL(@codbar, ''), ISNULL(@codalt, ''),
             ISNULL(@coduni, 1), ISNULL(@medalt, 0), ISNULL(@activo, 1),
             ISNULL(@exentoArt, 0), ISNULL(@imp_adi, 0),
             ISNULL(@impbase, 0), ISNULL(@impvariable, 0),
             ISNULL(@preciovar, 0), ISNULL(@balanza, 0), ISNULL(@coment, ''),
             0, 1, 1,
             GETDATE(), 'SYNC', GETDATE(), 'SYNC', GETDATE());
END
GO

-- -------------------------------- CLIENTE -----------------------------------
-- Clave natural: RUT. El merge de RUT duplicado entre cajas lo resuelve el
-- master; aquí solo se aplica el estado que el master confirme.
IF OBJECT_ID(N'dbo.sp_ApiPos_Cliente_Apply', N'P') IS NOT NULL DROP PROCEDURE dbo.sp_ApiPos_Cliente_Apply;
GO
CREATE PROCEDURE dbo.sp_ApiPos_Cliente_Apply
    @rutcte    INT,
    @digcte    VARCHAR(1),
    @nomcte    VARCHAR(200),
    @gircte    VARCHAR(200) = '',
    @dircte    VARCHAR(200) = '',
    @comcte    INT          = 0,
    @emacte    VARCHAR(100) = '',
    @foncte1   VARCHAR(20)  = '',
    @codlis    INT          = 1,
    @codpag    INT          = 1,
    @status    INT          = 0,
    @operation VARCHAR(10)  = 'upsert'
AS
BEGIN
    SET NOCOUNT ON;

    IF @operation = 'delete'
    BEGIN
        UPDATE dbo.conCtacte SET status = 1 WHERE rutcte = @rutcte;
        RETURN;
    END

    IF EXISTS (SELECT 1 FROM dbo.conCtacte WHERE rutcte = @rutcte)
        UPDATE dbo.conCtacte
           SET digcte = @digcte, nomcte = @nomcte, gircte = @gircte,
               dircte = @dircte, comcte = @comcte, emacte = @emacte,
               foncte1 = @foncte1, codlis = @codlis, codpag = @codpag,
               status = @status, logmod = 'SYNC', fecmod = GETDATE()
         WHERE rutcte = @rutcte;
    ELSE
        INSERT INTO dbo.conCtacte
            (rutcte, codcte, digcte, nomcte, gircte, dircte, comcte, emacte, foncte1,
             codlis, codpag, status, tipo, loging, logmod, fecing, fecmod)
        VALUES
            (@rutcte, CONVERT(VARCHAR(50), @rutcte), @digcte, @nomcte, @gircte, @dircte,
             @comcte, @emacte, @foncte1, @codlis, @codpag, @status, 1, 'SYNC', 'SYNC',
             GETDATE(), GETDATE());
END
GO

-- ------------------------------ PROMOCIÓN -----------------------------------
-- Cabecera de promoción (pvtPromociones, PK (tipo, idpromocion)).
-- Los parámetros en NULL significan "no vino en el evento": el UPDATE conserva
-- el valor de la columna y el INSERT usa el default de la tabla. Un campo que
-- llega con 0 sí se escribe como 0.
-- Con @reemplazarFiltros = 1 el upsert BORRA los filtros existentes y el agente
-- reinserta el set completo con sp_ApiPos_PromocionFiltro_Apply dentro de la
-- MISMA transacción. Con 0 (evento sin lista de filtros) los filtros quedan
-- intactos.
IF COL_LENGTH(N'dbo.pvtPromocionesFiltro', N'cantidad') IS NULL
    ALTER TABLE dbo.pvtPromocionesFiltro ADD cantidad DECIMAL(18,4) NOT NULL
        CONSTRAINT DF_pvtPromocionesFiltro_cantidad DEFAULT (0);
GO
IF OBJECT_ID(N'dbo.sp_ApiPos_Promocion_Apply', N'P') IS NOT NULL DROP PROCEDURE dbo.sp_ApiPos_Promocion_Apply;
GO
CREATE PROCEDURE dbo.sp_ApiPos_Promocion_Apply
    @tipo          INT,
    @idpromocion   VARCHAR(50),
    @descripcion   VARCHAR(200),
    @tipodescuento INT           = NULL,
    @fecini        DATETIME      = NULL,
    @fecfin        DATETIME      = NULL,
    @activo        INT           = NULL,
    @valida        INT           = NULL,
    @cantidad      DECIMAL(18,4) = NULL,
    @monto         DECIMAL(18,4) = NULL,
    @porcentaje    DECIMAL(18,4) = NULL,
    @montocupon    DECIMAL(18,4) = NULL,
    @cantidadcupones DECIMAL(18,4) = NULL,
    @todo          INT           = NULL,
    @listaprecio   INT           = NULL,
    @rf1 INT = NULL, @rf2 INT = NULL, @rf3 INT = NULL, @rf4 INT = NULL, @rf5 INT = NULL, @rf6 INT = NULL, @rf7 INT = NULL,
    @valorrf1 INT = NULL, @valorrf2 INT = NULL, @valorrf3 INT = NULL, @valorrf4 INT = NULL, @valorrf5 INT = NULL, @valorrf6 INT = NULL, @valorrf7 INT = NULL,
    @valorrf1Fijo INT = NULL, @valorrf2Fijo INT = NULL, @valorrf3Fijo INT = NULL, @valorrf4Fijo INT = NULL, @valorrf5Fijo INT = NULL, @valorrf6Fijo INT = NULL, @valorrf7Fijo INT = NULL,
    @n             INT           = NULL,
    @m             INT           = NULL,
    @agrupar       INT           = NULL,
    @sobrerango    INT           = NULL,
    @reemplazarFiltros BIT       = 1,
    @operation     VARCHAR(10)   = 'upsert'
AS
BEGIN
    SET NOCOUNT ON;

    IF @operation = 'delete'
    BEGIN
        -- La promoción eliminada en el central queda desactivada en la caja.
        UPDATE dbo.pvtPromociones
           SET activo = 0, logmod = 'SYNC', fecmod = GETDATE(), host_mod = HOST_NAME()
         WHERE tipo = @tipo AND idpromocion = @idpromocion;
        RETURN;
    END

    IF EXISTS (SELECT 1 FROM dbo.pvtPromociones WHERE tipo = @tipo AND idpromocion = @idpromocion)
        UPDATE dbo.pvtPromociones
           SET descripcion = @descripcion,
               tipodescuento = ISNULL(@tipodescuento, tipodescuento),
               fecini = ISNULL(@fecini, fecini), fecfin = ISNULL(@fecfin, fecfin),
               activo = ISNULL(@activo, activo), valida = ISNULL(@valida, valida),
               cantidad = ISNULL(@cantidad, cantidad), monto = ISNULL(@monto, monto),
               porcentaje = ISNULL(@porcentaje, porcentaje),
               montocupon = ISNULL(@montocupon, montocupon),
               cantidadcupones = ISNULL(@cantidadcupones, cantidadcupones),
               todo = ISNULL(@todo, todo), listaprecio = ISNULL(@listaprecio, listaprecio),
               rf1 = ISNULL(@rf1, rf1), rf2 = ISNULL(@rf2, rf2), rf3 = ISNULL(@rf3, rf3), rf4 = ISNULL(@rf4, rf4),
               rf5 = ISNULL(@rf5, rf5), rf6 = ISNULL(@rf6, rf6), rf7 = ISNULL(@rf7, rf7),
               valorrf1 = ISNULL(@valorrf1, valorrf1), valorrf2 = ISNULL(@valorrf2, valorrf2),
               valorrf3 = ISNULL(@valorrf3, valorrf3), valorrf4 = ISNULL(@valorrf4, valorrf4),
               valorrf5 = ISNULL(@valorrf5, valorrf5), valorrf6 = ISNULL(@valorrf6, valorrf6),
               valorrf7 = ISNULL(@valorrf7, valorrf7),
               valorrf1Fijo = ISNULL(@valorrf1Fijo, valorrf1Fijo), valorrf2Fijo = ISNULL(@valorrf2Fijo, valorrf2Fijo),
               valorrf3Fijo = ISNULL(@valorrf3Fijo, valorrf3Fijo), valorrf4Fijo = ISNULL(@valorrf4Fijo, valorrf4Fijo),
               valorrf5Fijo = ISNULL(@valorrf5Fijo, valorrf5Fijo), valorrf6Fijo = ISNULL(@valorrf6Fijo, valorrf6Fijo),
               valorrf7Fijo = ISNULL(@valorrf7Fijo, valorrf7Fijo),
               n = ISNULL(@n, n), m = ISNULL(@m, m), agrupar = ISNULL(@agrupar, agrupar),
               sobrerango = ISNULL(@sobrerango, sobrerango),
               logmod = 'SYNC', fecmod = GETDATE(), host_mod = HOST_NAME()
         WHERE tipo = @tipo AND idpromocion = @idpromocion;
    ELSE
        INSERT INTO dbo.pvtPromociones
            (tipo, idpromocion, descripcion, tipodescuento, fecini, fecfin, activo, valida,
             cantidad, monto, porcentaje, montocupon, cantidadcupones, todo, listaprecio,
             rf1, rf2, rf3, rf4, rf5, rf6, rf7,
             valorrf1, valorrf2, valorrf3, valorrf4, valorrf5, valorrf6, valorrf7,
             valorrf1Fijo, valorrf2Fijo, valorrf3Fijo, valorrf4Fijo, valorrf5Fijo, valorrf6Fijo, valorrf7Fijo,
             n, m, agrupar, sobrerango, loging, logmod, fecing, host_ing, fecmod)
        VALUES
            (@tipo, @idpromocion, @descripcion, ISNULL(@tipodescuento, 0),
             ISNULL(@fecini, '19000101'), ISNULL(@fecfin, '19000101'),
             ISNULL(@activo, 1), ISNULL(@valida, 1),
             ISNULL(@cantidad, 0), ISNULL(@monto, 0), ISNULL(@porcentaje, 0),
             ISNULL(@montocupon, 0), ISNULL(@cantidadcupones, 0),
             ISNULL(@todo, 0), ISNULL(@listaprecio, 0),
             ISNULL(@rf1, 0), ISNULL(@rf2, 0), ISNULL(@rf3, 0), ISNULL(@rf4, 0),
             ISNULL(@rf5, 0), ISNULL(@rf6, 0), ISNULL(@rf7, 0),
             ISNULL(@valorrf1, 0), ISNULL(@valorrf2, 0), ISNULL(@valorrf3, 0), ISNULL(@valorrf4, 0),
             ISNULL(@valorrf5, 0), ISNULL(@valorrf6, 0), ISNULL(@valorrf7, 0),
             ISNULL(@valorrf1Fijo, 0), ISNULL(@valorrf2Fijo, 0), ISNULL(@valorrf3Fijo, 0), ISNULL(@valorrf4Fijo, 0),
             ISNULL(@valorrf5Fijo, 0), ISNULL(@valorrf6Fijo, 0), ISNULL(@valorrf7Fijo, 0),
             ISNULL(@n, 0), ISNULL(@m, 0), ISNULL(@agrupar, 0), ISNULL(@sobrerango, 0),
             'SYNC', 'SYNC', GETDATE(), HOST_NAME(), GETDATE());

    IF @reemplazarFiltros = 1
        DELETE FROM dbo.pvtPromocionesFiltro WHERE tipo = @tipo AND idpromocion = @idpromocion;
END
GO

-- Filtro de promoción (una línea por llamada, misma transacción del agente).
-- @cantidad es la cantidad por artículo de los packs; el resto de los tipos
-- graba 0, igual que el formulario de promociones.
IF OBJECT_ID(N'dbo.sp_ApiPos_PromocionFiltro_Apply', N'P') IS NOT NULL DROP PROCEDURE dbo.sp_ApiPos_PromocionFiltro_Apply;
GO
CREATE PROCEDURE dbo.sp_ApiPos_PromocionFiltro_Apply
    @tipo        INT,
    @idpromocion VARCHAR(50),
    @linea       INT,
    @tipofiltro  INT           = 0,
    @codfam      VARCHAR(50)   = '',
    @codsub      VARCHAR(50)   = '',
    @codbus      VARCHAR(50)   = '',
    @cantidad    DECIMAL(18,4) = 0
AS
BEGIN
    SET NOCOUNT ON;

    INSERT INTO dbo.pvtPromocionesFiltro
        (tipo, idpromocion, linea, tipofiltro, codfam, codsub, codbus, cantidad,
         loging, logmod, fecing, host_ing)
    VALUES
        (@tipo, @idpromocion, @linea, @tipofiltro, @codfam, @codsub, @codbus, ISNULL(@cantidad, 0),
         'SYNC', 'SYNC', GETDATE(), HOST_NAME());
END
GO

-- -------------------------------- PRECIO ------------------------------------
-- Línea de lista de precios (venListaDetalleRango, PK codlis+codbus). La
-- caja mantiene solo el precio vigente para vender; el histórico de
-- tarifas vive en el master, no en el POS. delete = quitar la línea.
IF OBJECT_ID(N'dbo.sp_ApiPos_Precio_Apply', N'P') IS NOT NULL DROP PROCEDURE dbo.sp_ApiPos_Precio_Apply;
GO
CREATE PROCEDURE dbo.sp_ApiPos_Precio_Apply
    @codlis    INT,
    @codbus    VARCHAR(50),
    @rf1 DECIMAL(18,4) = 0, @valor1 DECIMAL(18,4) = 0, @valorBruto1 DECIMAL(18,4) = 0,
    @rf2 INT = 0, @valor2 DECIMAL(18,4) = 0, @valorBruto2 DECIMAL(18,4) = 0,
    @rf3 INT = 0, @valor3 DECIMAL(18,4) = 0, @valorBruto3 DECIMAL(18,4) = 0,
    @rf4 INT = 0, @valor4 DECIMAL(18,4) = 0, @valorBruto4 DECIMAL(18,4) = 0,
    @rf5 INT = 0, @valor5 DECIMAL(18,4) = 0, @valorBruto5 DECIMAL(18,4) = 0,
    @rf6 INT = 0, @valor6 DECIMAL(18,4) = 0, @valorBruto6 DECIMAL(18,4) = 0,
    @rf7 INT = 0, @valor7 DECIMAL(18,4) = 0, @valorBruto7 DECIMAL(18,4) = 0,
    @margen    DECIMAL(18,4) = 0,
    @operation VARCHAR(10)   = 'upsert'
AS
BEGIN
    SET NOCOUNT ON;

    IF @operation = 'delete'
    BEGIN
        DELETE FROM dbo.venListaDetalleRango WHERE codlis = @codlis AND codbus = @codbus;
        RETURN;
    END

    IF EXISTS (SELECT 1 FROM dbo.venListaDetalleRango WHERE codlis = @codlis AND codbus = @codbus)
        UPDATE dbo.venListaDetalleRango
           SET rf1 = @rf1, valor1 = @valor1, valorBruto1 = @valorBruto1,
               rf2 = @rf2, valor2 = @valor2, valorBruto2 = @valorBruto2,
               rf3 = @rf3, valor3 = @valor3, valorBruto3 = @valorBruto3,
               rf4 = @rf4, valor4 = @valor4, valorBruto4 = @valorBruto4,
               rf5 = @rf5, valor5 = @valor5, valorBruto5 = @valorBruto5,
               rf6 = @rf6, valor6 = @valor6, valorBruto6 = @valorBruto6,
               rf7 = @rf7, valor7 = @valor7, valorBruto7 = @valorBruto7,
               margen = @margen, logmod = 'SYNC', fecmod = GETDATE()
         WHERE codlis = @codlis AND codbus = @codbus;
    ELSE
        INSERT INTO dbo.venListaDetalleRango
            (codlis, codbus, rf1, valor1, valorBruto1, rf2, valor2, valorBruto2,
             rf3, valor3, valorBruto3, rf4, valor4, valorBruto4,
             rf5, valor5, valorBruto5, rf6, valor6, valorBruto6,
             rf7, valor7, valorBruto7, margen, loging, fecing, logmod, fecmod)
        VALUES
            (@codlis, @codbus, @rf1, @valor1, @valorBruto1, @rf2, @valor2, @valorBruto2,
             @rf3, @valor3, @valorBruto3, @rf4, @valor4, @valorBruto4,
             @rf5, @valor5, @valorBruto5, @rf6, @valor6, @valorBruto6,
             @rf7, @valor7, @valorBruto7, @margen, 'SYNC', GETDATE(), 'SYNC', GETDATE());
END
GO

-- =============================================================================
-- ROLLBACK (ejecutar solo para revertir):
-- DROP PROCEDURE IF EXISTS dbo.sp_ApiPos_Precio_Apply;
-- DROP PROCEDURE IF EXISTS dbo.sp_ApiPos_PromocionFiltro_Apply;
-- DROP PROCEDURE IF EXISTS dbo.sp_ApiPos_Promocion_Apply;
-- DROP PROCEDURE IF EXISTS dbo.sp_ApiPos_Cliente_Apply;
-- DROP PROCEDURE IF EXISTS dbo.sp_ApiPos_Articulo_Apply;
-- DROP PROCEDURE IF EXISTS dbo.sp_ApiPos_SubFamilia_Apply;
-- DROP PROCEDURE IF EXISTS dbo.sp_ApiPos_Familia_Apply;
-- =============================================================================

/* ===================== 2) LIMPIEZA ===================== */
SET QUOTED_IDENTIFIER ON;
GO
EXEC dbo.sp_ApiPos_Articulo_Apply @codfam = '1', @codsub = '99', @codart = '2021', @nomart = '', @operation = 'delete';
EXEC dbo.sp_ApiPos_Articulo_Apply @codfam = '1', @codsub = '99', @codart = '2020', @nomart = '', @operation = 'delete';
EXEC dbo.sp_ApiPos_Articulo_Apply @codfam = '1', @codsub = '99', @codart = '3030', @nomart = '', @operation = 'delete';
EXEC dbo.sp_ApiPos_Articulo_Apply @codfam = '1', @codsub = '28', @codart = '1418', @nomart = '', @operation = 'delete';
EXEC dbo.sp_ApiPos_Articulo_Apply @codfam = '1', @codsub = '10', @codart = '8787', @nomart = '', @operation = 'delete';
GO

/* ===================== 3) VERIFICACION (debe devolver 0 filas) ===================== */
SELECT codfam, codsub, codart, nomart FROM dbo.invArticulos
 WHERE (codfam = '1' AND codsub = '99' AND codart IN ('2021', '2020', '3030'))
    OR (codfam = '1' AND codsub = '28' AND codart = '1418')
    OR (codfam = '1' AND codsub = '10' AND codart = '8787');
