ALTER PROCEDURE [dbo].[sp_remPagoBancario_Excel_BCHILE]
(
	@fichaini INT = 0,
	@fichafin INT = 99999999,
	@unineg INT = 0,
	@idconcepto INT = 0,
	@periodo INT = 0,
	@mes INT = 0,
	@descripcionPago VARCHAR(100) = ''
)
AS

SELECT
	CASE
		WHEN T.banco = 1 THEN 1
		WHEN ISNUMERIC(FP.codigobchile) = 1 THEN CONVERT(INT, FP.codigobchile)
		ELSE 0
	END											AS medioPago,
	T.rut										AS rutBeneficiario,
	T.dv										AS dvBeneficiario,
	LTRIM(RTRIM(T.apePaterno)) + ' ' + LTRIM(RTRIM(T.apeMaterno)) + ' ' + LTRIM(RTRIM(T.nombres)) AS nombreBeneficiario,
	T.banco										AS codigoBanco,
	T.numCuenta									AS numeroCuenta,
	CONVERT(INT, RM.valor)						AS montoPago,
	@descripcionPago							AS descripcionPago,	
	T.correoPart								AS mailDestino,		
	''											AS mensaje
FROM remTrabajadores T
INNER JOIN remMovimientosRM RM ON T.ficha = RM.ficha
	AND T.periodo = RM.periodo
	AND T.mes = RM.mes
LEFT JOIN remFormasPago FP ON FP.idFormaPago = T.formaPago
WHERE (T.ficha BETWEEN @fichaini AND @fichafin)
AND (T.unidadNegocios = @unineg OR @unineg = 0)
AND RM.tipoConcepto = 'R'
AND RM.idConcepto = @idconcepto
AND T.periodo = @periodo
AND T.mes = @mes
AND T.activo = 1
AND T.formaPago >= 3 
ORDER BY nombreBeneficiario ASC
GO
