CREATE PROCEDURE [dbo].[sp_remPagoBancario_Excel_BCI]
(
	@fichaini INT = 0,
	@fichafin INT = 99999999,
	@unineg INT = 0,
	@idconcepto INT = 0,
	@periodo INT = 0,
	@mes INT = 0,
	@ctaCargo VARCHAR(30) = '',
	@mensaje VARCHAR(100) = ''
)
AS

-- Nomina bancaria BCI en Excel (ticket PJ-3367). Mismas reglas que el flujo de Banco de Chile:
-- monto desde remMovimientosRM (tipoConcepto 'R'), solo abonos a cuenta (formaPago >= 3).
-- Devuelve las 13 columnas de la hoja "Registros" de la plantilla de carga del BCI, en orden.
SELECT
	@ctaCargo										AS ctaCargo,			-- 1  Numero Cuenta de Cargo (cuenta de la empresa)
	T.numCuenta										AS ctaDestino,			-- 2  Numero Cuenta de Destino
	-- 3  Codigo Banco Destino (codigo CCA). El BCI esta duplicado en conBancos (16 y 56);
	--    ambos son BCI pero la plantilla solo acepta 16, por eso se mapea 56 -> 16.
	CASE WHEN T.banco = 56 THEN 16 ELSE T.banco END	AS codBanco,
	T.rut											AS rutDestino,			-- 4  Rut Destinatario
	T.dv											AS dvDestino,			-- 5  Digito Verificador
	LTRIM(RTRIM(T.apePaterno)) + ' ' + LTRIM(RTRIM(T.apeMaterno)) + ' ' + LTRIM(RTRIM(T.nombres)) AS nombreDestino, -- 6 Nombre Destinatario
	CONVERT(INT, RM.valor)							AS montoTransferencia,	-- 7  Monto Transferencia
	''												AS facturaBoleta,		-- 8  Factura / Boleta
	''												AS nroDocumento,		-- 9  Numero Documento
	'REM'											AS tipoPago,			-- 10 Tipo de Pago
	@mensaje										AS mensajeDestino,		-- 11 Mensaje Destinatario (concepto de la ventana)
	T.correoPart									AS emailDestino,		-- 12 Email Destinatario (correo particular de la ficha)
	''												AS aliasDestino			-- 13 Alias
FROM remTrabajadores T
INNER JOIN remMovimientosRM RM ON T.ficha = RM.ficha
	AND T.periodo = RM.periodo
	AND T.mes = RM.mes
WHERE (T.ficha BETWEEN @fichaini AND @fichafin)
AND (T.unidadNegocios = @unineg OR @unineg = 0)
AND RM.tipoConcepto = 'R'
AND RM.idConcepto = @idconcepto
AND T.periodo = @periodo
AND T.mes = @mes
AND T.activo = 1
AND T.formaPago >= 3
ORDER BY nombreDestino ASC
GO
