CREATE PROCEDURE dbo.sp_remActualizaMasivoFicha
    @fichas         XML,
    @periodo        INT,
    @mes            INT,
    @actHoras       BIT,
    @cantidadHoras  DECIMAL(9,2),
    @actContrato    BIT,
    @tipoContrato   INT,
    @actJornada     BIT,
    @tipoJornada    INT,
    @actTrabajador  BIT,
    @tipoTrabajador INT,
    @actSucursal    BIT,
    @codSucursal    INT,
    @nomSucursal    VARCHAR(100),
    @comSucursal    INT,
    @dirSucursal    VARCHAR(150),
    @ciuSucursal    VARCHAR(100)
AS
BEGIN
    SET NOCOUNT ON;

    -- Fichas marcadas, recibidas como XML: <fichas><f>1</f><f>2</f></fichas>
    DECLARE @lista TABLE (ficha INT);
    INSERT INTO @lista (ficha)
    SELECT X.c.value('.', 'INT')
    FROM @fichas.nodes('/fichas/f') AS X(c);

    UPDATE T SET
        cantidadHoras  = CASE WHEN @actHoras      = 1 THEN @cantidadHoras  ELSE T.cantidadHoras  END,
        tipoContrato   = CASE WHEN @actContrato   = 1 THEN @tipoContrato   ELSE T.tipoContrato   END,
        tipoJornada    = CASE WHEN @actJornada    = 1 THEN @tipoJornada    ELSE T.tipoJornada    END,
        tipoTrabajador = CASE WHEN @actTrabajador = 1 THEN @tipoTrabajador ELSE T.tipoTrabajador END,
        codSucursal    = CASE WHEN @actSucursal   = 1 THEN @codSucursal    ELSE T.codSucursal    END,
        nomSucursal    = CASE WHEN @actSucursal   = 1 THEN @nomSucursal    ELSE T.nomSucursal    END,
        comSucursal    = CASE WHEN @actSucursal   = 1 THEN @comSucursal    ELSE T.comSucursal    END,
        dirSucursal    = CASE WHEN @actSucursal   = 1 THEN @dirSucursal    ELSE T.dirSucursal    END,
        ciuSucursal    = CASE WHEN @actSucursal   = 1 THEN @ciuSucursal    ELSE T.ciuSucursal    END
    FROM remTrabajadores T
    INNER JOIN @lista L ON T.ficha = L.ficha
    WHERE T.periodo = @periodo AND T.mes = @mes;

    SELECT @@ROWCOUNT AS FilasActualizadas;
END
GO
