CREATE PROCEDURE sp_Api5_AppFac_pvtCajaCierre
    @correlativo BIGINT,
    @sucursal VARCHAR(10),
    @caja VARCHAR(10),
    @cajerocierre INT,
    @logincierre VARCHAR(50),
    @totalventas DECIMAL(18,2),
    @totalentradas DECIMAL(18,2),
    @totalsalidas DECIMAL(18,2),
    @totalefectivo DECIMAL(18,2),
    @efectivocaja DECIMAL(18,2),
    @diferencia DECIMAL(18,2),
    @efectivo DECIMAL(18,2),
    @comentario VARCHAR(500)
AS
BEGIN
    SET NOCOUNT ON;
    BEGIN TRY
        BEGIN TRANSACTION;

        IF NOT EXISTS (
            SELECT 1 FROM pvtMovCajaEnc
            WHERE tipo = 1 AND estado = 0 AND correlativocierre = @correlativo
        )
        BEGIN
            RAISERROR('No existe apertura abierta con correlativo: %I64d', 16, 1, @correlativo);
            RETURN;
        END

        UPDATE pvtMovCajaEnc SET
            estado = 1,
            fechacierre = GETDATE(),
            cajerocierre = @cajerocierre,
            logincierre = @logincierre,
            totalventas = @totalventas,
            totalentradas = @totalentradas,
            totalsalidas = @totalsalidas,
            totalefectivo = @totalefectivo,
            efectivocaja = @efectivocaja,
            diferencia = @diferencia,
            efectivo = @efectivo,
            comentario = @comentario
        WHERE tipo = 1 AND correlativocierre = @correlativo;

        UPDATE pvtRegistroCajas SET idcierre = @correlativo
        WHERE idcierre = 0 AND sucursal = @sucursal AND caja = @caja;

        UPDATE pvtCajas SET cajero = 0, host = '', cierre = 0
        WHERE sucursal = @sucursal AND codigo = @caja;

        COMMIT TRANSACTION;

        SELECT @correlativo AS correlativo, 'Caja cerrada correctamente' AS mensaje;
    END TRY
    BEGIN CATCH
        IF @@TRANCOUNT > 0 ROLLBACK TRANSACTION;
        THROW;
    END CATCH
END